Arduino RFID 门锁系统 – RC522 模块实现安全门禁

元件与材料

项目简介

演示如何用 Arduino UNO 和 RC522 模块制作 RFID 门锁。授权卡触发舵机转动 90° 开锁 1 秒后自动关锁，NeoPixel 绿灯指示成功，红灯指示拒绝。项目也发布在 geek.adachsoft.com。

步骤 1：元件清单

• Arduino UNO
• RFID RC522
• TG9e 舵机
• WS2812 RGB LED
• 2× RFID 标签

步骤 2：原理图

步骤 3：软件逻辑

初始化串口、SPI、RC522、舵机、NeoPixel。循环检测新卡，读取 UID 并转为十六进制字符串（如 "77-39-50-39"）。与预设授权 UID 比对，匹配则舵机转 90°、绿灯亮 1 秒后复位；不匹配则红灯亮 0.5 秒。串口输出 UID 及授权结果。

代码

RFID_with_servo.ino

/* https://geek.adachsoft.com */
#include <SPI.h>
#include <MFRC522.h>
#include <Servo.h>
#include <Adafruit_NeoPixel.h>
#define LED_PIN A0
Adafruit_NeoPixel pixels = Adafruit_NeoPixel(1, LED_PIN, NEO_GRB + NEO_KHZ800);
#define SERVO_PIN 3
Servo myservo;
#define SS_PIN 10
#define RST_PIN 9
MFRC522 mfrc522(SS_PIN, RST_PIN);

void setup() {
  Serial.begin(115200);
  SPI.begin();
  mfrc522.PCD_Init();
  Serial.println("For more: https://geek.adachsoft.com");
  Serial.println("Arduino RFID lock");
  Serial.println("");
  myservo.attach(SERVO_PIN);
  myservo.write(0);
  pixels.begin();
  pixels.setPixelColor(0, 32, 32, 32); pixels.show(); delay(500);
  pixels.setPixelColor(0, 0, 0, 0); pixels.show();
}

void loop() {
  if (!mfrc522.PICC_IsNewCardPresent()) return;
  if (!mfrc522.PICC_ReadCardSerial()) return;
  String content = "";
  for (byte i = 0; i < mfrc522.uid.size; i++) {
    content.concat(String(mfrc522.uid.uidByte[i], HEX));
    if (i < mfrc522.uid.size - 1) content += "-";
  }
  content.toUpperCase();
  Serial.println(); Serial.println("UID tag :'" + content + "'");
  if (content == "77-39-50-39") {
    Serial.println("Authorized access");
    myservo.write(90);
    pixels.setPixelColor(0, 0, 32, 0); pixels.show();
    delay(1000);
    myservo.write(0);
    pixels.setPixelColor(0, 0, 0, 0); pixels.show();
  } else {
    Serial.println("Access denied");
    pixels.setPixelColor(0, 32, 0, 0); pixels.show();
    delay(500);
    pixels.setPixelColor(0, 0, 0, 0); pixels.show();
  }
  delay(1000);
}

原理图