亿迅智能制造网
工业4.0先进制造技术信息网站!
首页 | 制造技术 | 制造设备 | 工业物联网 | 工业材料 | 设备保养维修 | 工业编程 |
home  MfgRobots >> 亿迅智能制造网 >  >> Manufacturing Technology >> 制造工艺

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目

组件与物料

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
RGB漫射共阴极LED
眼睛
×2
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
SparkFun 7段串口显示屏 - 红
计时器
×1
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
TI 74HC165 并转串移位寄存器
4位7段显示
×1
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
字母数字LCD,16×2
菜单显示
×1
IR接收器(通用)
遥控用
×1
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
Arduino UNO
核心控制器
×1
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
SG90微型舵机
转动头部
×1
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
PIR人体红外传感器(通用)
运动检测
×1
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
超声波测距模块 HC-SR04
判定胜负的距离检测
×1
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
DFRobot DFPlayer Mini MP3模块
语音播放
×1
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
轻触开关
菜单键与开始键
×1

必需工具与设备

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
3D打印机(通用)

应用与在线服务

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
Arduino IDE

项目简介

制作一个功能完整的《鱿鱼游戏》娃娃。她能与你玩“红灯绿灯”游戏。具备转头、变色眼睛、语音播报。利用超声波与运动检测判定输赢。输了也别怕,她只会问你要不要再玩一次。

观看视频并留下你的想法。

我用尽了Arduino UNO所有引脚!这是我从未做过的事,也是个人成就。项目耗时3周:1周打印(整整6天),1周组装,1周剪辑视频。

ELEGOO赞助免费UNO套件条件是制作视频,所以才有了这个娃娃。原本可以做密室逃脱,但我庆幸他们选了这个。希望大家喜欢,外观酷炫又吓人,最重要的是——它能跑通。

以下是全部用料清单。

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目

1. 开始打印

打印耗时极长,完整娃娃花了6天。我用不同颜色耗材减少喷漆工作量。

我在Thingiverse找到模型并改造:挖空内部、预留电子舱孔、修改胸板安装舵机与超声波模块。

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目

2. 油漆最烦人

用通用喷漆。娃娃头部内侧喷漆(遮蔽眼睛),让LED只发亮眼睛,不让整张脸发光。

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目

3. 磁铁吸引但胶水更牢

肢体连接可用磁铁熔入塑料,方便拆卸收纳。但回头看,直接粘胶更省事,磁铁优势仅是收纳更紧凑。头部暂不粘连。

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目

4. 眼睛最简单

用三色LED做眼睛,通过RGB混色可得任意颜色。我只用基础色避免PWM。最长脚为公共地(接Pin 2)。

每引脚串联220Ω电阻(地除外)。热熔胶将LED固定在眼球中心背面,预留足长导线穿过脖颈进入躯干。

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目

5. LCD菜单

建议用带I2C适配器的16×2 LCD,IO从6脚降至2脚。接好后开机显示“Welcome to the squid games!”

安装:打印1mm厚圆盘,热风枪烤弯贴合背部曲面,比设计轮廓容易得多。用热熔螺母固定屏幕与支架。

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目

6. 只有猫头鹰能转180度

舵机控制棘手:我不想用Servo库,因为Timer1被4位数码管刷新占用。幸好舵机只需0°/180°两档,简化控制。

Timer1设为0.5ms周期(2kHz),舵机周期20ms。0°时高电平2个计数,其余低;180°时高4个计数。胸板有安装座,用环氧胶固定舵机并加强胸板。

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目

7. 蝙蝠般的超声波

超声波模块250ms更新一次,胸板有专用安装位,仅两根线。用环氧胶固定。

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目

8. 红外遥控可选

IR接收器仅用于遥控模式,我平时用自动模式更有趣。我把IR藏在头发夹子里,但转头时可能遮挡,后续可优化位置。

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目

9. 计时器显示

4位数码管驱动繁琐,附上ELEGOO接线图。游戏最长5分钟,省去最高位。2ms刷新率肉眼无闪烁,5ms边缘视觉可见闪烁。需配合74HC595移位寄存器。

安装最麻烦:我把显示器嵌入腰带(原版娃娃无腰带,妥协之举)。遮蔽切割、环氧腻子过渡美观。74HC595焊在扩展板上避免飞线。也可换更省脚的显示模块。

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目

10. 我看见你动了

PIR传感器需1分钟预热,故开机有1分钟倒计时。最快5秒更新一次,灵敏度极高(即使调最低仍误触)。为抑制误报,我设计“马眼罩”盒:仅留7mm小孔,内部螺纹嵌入固定传感器,避免外露巨大模块。

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目

11. 别按我的键

IO不足,用单路模拟口读电阻分压识别按键:1K、2K、5K分压,外加220Ω下拉防浮动。按键与LCD共用安装板,焊线穿孔极考验耐心。

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目

12. 听得见吗?

DFPlayer占用串口,Tx/Rx须串1KΩ电阻,否则接上后无法烧录。必须用Busy引脚判断播放状态,防止连播冲突。模块焊在扩展板,插UNO即用。配8Ω/3W扬声器,粘在底座,底部钻小孔出声。

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目

13. 装载UNO

UNO固定底板,插上扩展板。务必给所有线贴标签,否则理不清。稍加协商即可塞入娃娃底部。底板用热熔螺母锁死。

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目

14. 测试-修-再测

软件已在GitHub验证,硬件调试自行进行,欢迎反馈改进。

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目

15. 开始游戏

游戏逻辑:

  • 开机头朝前,PIR预热1分钟。30秒时笑一下并转头,10秒播报“准备好啦”。
  • 自动模式:提示按“Go键”(最右键);遥控模式:提示按遥控电源键准备,再按播放键切换红/绿灯。
  • 按Go后给10秒就位(通常由旁人按)。
  • 绿灯:超声波检测<50cm判胜,<100cm提示“靠近了”。仅用超声波。
  • 红灯:PIR+超声波双重判定。PIR触发或距离前移>10cm即判负。时间耗尽也判负。最后5秒语音催促。
  • 菜单:最左键切项目(语言/时长/模式),中间键切选项。支持韩语“红灯”语音。

16. 观看视频

剪辑耗时约30小时,但很有趣。成品不错且搞笑,欢迎围观:https://youtu.be/jd_4a4x3uCw

谢谢!

代码

  • Squid Game Doll Sketch
Squid Game Doll SketchC/C++

控制所有传感器与游戏逻辑。

/// CodeMakesItGo Dec 2021
#include <DFPlayerMini_Fast.h>
#include <FireTimer.h>
#include <IRremote.h>
#include <LiquidCrystal_I2C.h>
#include <SoftwareSerial.h>
#include <SR04.h>
#include <Wire.h>
/*-----( 模拟引脚 )-----*/
#define BUTTONS_IN A0
#define SONAR_TRIG_PIN A1
#define SONAR_ECHO_PIN A2
#define MOTION_IN A3
/*-----( 数字引脚 )-----*/
#define LED_BLUE 13
#define LED_GREEN 12
#define LED_RED 11
#define SEGMENT_DATA 10 // DS
#define SEGMENT_CLOCK 9 // SHCP
#define SEGMENT_LATCH 8 // STCP
#define SEGMENT_1_OUT 7
#define SEGMENT_2_OUT 6
#define SEGMENT_3_OUT 5
#define IR_DIGITAL_IN 4 // IR遥控
#define SERVO_OUT 3
#define DFPLAYER_BUSY_IN 2
/*-----( 配置常量 )-----*/
#define TIMER_FREQUENCY 2000
#define TIMER_MATCH (int)(((16E+6) / (TIMER_FREQUENCY * 64.0)) - 1)
#define TIMER_2MS ((TIMER_FREQUENCY / 1000) * 2)
#define VOLUME 30 // 0-30
#define BETTER_HURRY_S 5 // 剩5秒播催促音
#define WIN_PROXIMITY_CM 50 // 胜利距离
#define CLOSE_PROXIMITY_CM 100 // 接近距离
#define GREEN_LIGHT_MS 3000 // 绿灯3秒
#define RED_LIGHT_MS 5000 // 红灯5秒
#define WAIT_FOR_STOP_MOTION_MS 5000 // 等待运动停止5秒
/*-----( 全局变量 )-----*/
static unsigned int timer_1000ms = 0;
static unsigned int timer_2ms = 0;
static unsigned char digit = 0; // 数码管位选
static int countDown = 60; // 开机1分钟倒计时
static const int sonarVariance = 10; // 距离变化阈值
static bool gameInPlay = false;
static bool faceTree = false;
static bool remotePlay = false;
// 0-9,A-F,NULL
const unsigned char numbers[] = {0x3f,0x06,0x5b,0x4f,0x66,0x6d,0x7d,0x07,0x7f,0x6f,0x77,0x7c,0x39,0x5e,0x79,0x71,0x00};
const char *MenuItems[] = {"Language","Play Time","Play Type"};
typedef enum {LANGUAGE,PLAYTIME,PLAYTYPE,MENUITEM_COUNT} MenuItemTypes;
const char *Languages[] = {"English","Korean"};
typedef enum {ENGLISH,KOREAN,LANUAGE_COUNT} LanguageTypes;
static int language = 0;
const char *PlayTime[] = {"300","240","180","120","60","30","15"};
typedef enum {PT300,PT240,PT180,PT120,PT60,PT30,PT15,PLAYTIME_COUNT} PlayTimeTypes;
const int playTimes[] = {300,240,180,120,60,30,15};
static int playTime = 0;
const char *PlayType[] = {"Auto","Remote"};
typedef enum {AUTO,REMOTE,PLAYTYPE_COUNT} PlayTypeTypes;
static int playType = 0;
typedef enum {BLACK,RED,GREEN,BLUE,WHITE,YELLOW,PURPLE} EyeColors;
EyeColors eyeColor = BLACK;
typedef enum {WARMUP,WAIT,READY,GREENLIGHT,REDLIGHT,WIN,LOSE} GameStates;
static GameStates gameState = WARMUP;
/*-----( 类对象 )-----*/
FireTimer task_50ms;
FireTimer task_250ms;
DFPlayerMini_Fast dfPlayer;
SR04 sonar = SR04(SONAR_ECHO_PIN, SONAR_TRIG_PIN);
IRrecv irRecv(IR_DIGITAL_IN);
decode_results irResults;
LiquidCrystal_I2C lcdDisplay(0x27, 16, 2); // 16x2 LCD
/*-----( 函数 )-----*/
void translateIR() {
  switch (irResults.value) {
    case 0xFFA25D: Serial.println("POWER"); if (gameState == WAIT) gameInPlay = true; break;
    case 0xFFE21D: Serial.println("FUNC/STOP"); break;
    case 0xFF629D: Serial.println("VOL+"); break;
    case 0xFF22DD: Serial.println("FAST BACK"); break;
    case 0xFF02FD: Serial.println("PAUSE"); remotePlay = !remotePlay; break;
    case 0xFFC23D: Serial.println("FAST FORWARD"); break;
    case 0xFFE01F: Serial.println("DOWN"); break;
    case 0xFFA857: Serial.println("VOL-"); break;
    case 0xFF906F: Serial.println("UP"); break;
    case 0xFF9867: Serial.println("EQ"); break;
    case 0xFFB04F: Serial.println("ST/REPT"); break;
    case 0xFF6897: Serial.println("0"); break;
    case 0xFF30CF: Serial.println("1"); break;
    case 0xFF18E7: Serial.println("2"); break;
    case 0xFF7A85: Serial.println("3"); break;
    case 0xFF10EF: Serial.println("4"); break;
    case 0xFF38C7: Serial.println("5"); break;
    case 0xFF5AA5: Serial.println("6"); break;
    case 0xFF42BD: Serial.println("7"); break;
    case 0xFF4AB5: Serial.println("8"); break;
    case 0xFF52AD: Serial.println("9"); break;
    case 0xFFFFFFFF: Serial.println(" REPEAT"); break;
    default: Serial.println(" other button ");
  }
}
bool isPlayingSound() { return (digitalRead(DFPLAYER_BUSY_IN) == LOW); }
void updateTimeDisplay(unsigned char digit, unsigned char num) {
  digitalWrite(SEGMENT_LATCH, LOW);
  shiftOut(SEGMENT_DATA, SEGMENT_CLOCK, MSBFIRST, numbers[num]); // 低电平有效
  digitalWrite(SEGMENT_1_OUT, digit == 1 ? LOW : HIGH);
  digitalWrite(SEGMENT_2_OUT, digit == 2 ? LOW : HIGH);
  digitalWrite(SEGMENT_3_OUT, digit == 3 ? LOW : HIGH);
  digitalWrite(SEGMENT_LATCH, HIGH);
}
void updateServoPosition() {
  static int servoPulseCount = 0;
  static bool lastPosition = false;
  if (servoPulseCount == 0) lastPosition = faceTree;
  if (!lastPosition) { digitalWrite(SERVO_OUT, servoPulseCount < 5 ? HIGH : LOW); }
  else { digitalWrite(SERVO_OUT, servoPulseCount < 1 ? HIGH : LOW); }
  servoPulseCount = (servoPulseCount + 1) % 40; // 20ms周期
}
void updateMenuDisplay(const int button) {
  static int menuItem = 0;
  static int menuOption = 0;
  switch (button) {
    case 1:
      menuItem = (menuItem + 1) % MENUITEM_COUNT;
      if (menuItem == LANGUAGE) menuOption = language;
      else if (menuItem == PLAYTIME) menuOption = playTime;
      else if (menuItem == PLAYTYPE) menuOption = playType;
      else menuOption = 0;
      break;
    case 2:
      if (menuItem == LANGUAGE) { menuOption = (menuOption + 1) % LANUAGE_COUNT; language = menuOption; }
      else if (menuItem == PLAYTIME) { menuOption = (menuOption + 1) % PLAYTIME_COUNT; playTime = menuOption; }
      else if (menuItem == PLAYTYPE) { menuOption = (menuOption + 1) % PLAYTYPE_COUNT; playType = menuOption; }
      else menuOption = 0;
      break;
    case 3:
      if (gameState == WAIT) gameInPlay = true;
      if (gameState == GREENLIGHT || gameState == REDLIGHT) gameInPlay = false;
    default: break;
  }
  if (menuOption != -1) {
    lcdDisplay.clear();
    lcdDisplay.setCursor(0, 0);
    lcdDisplay.print(MenuItems[menuItem]);
    lcdDisplay.setCursor(0, 1);
    if (menuItem == LANGUAGE) lcdDisplay.print(Languages[menuOption]);
    else if (menuItem == PLAYTIME) lcdDisplay.print(PlayTime[menuOption]);
    else if (menuItem == PLAYTYPE) lcdDisplay.print(PlayType[menuOption]);
    else lcdDisplay.print("unknown option");
  } else { menuItem = 0; menuOption = 0; }
}
void handleButtons() {
  static int buttonPressed = 0;
  int value = analogRead(BUTTONS_IN);
  if (value < 600) { if (buttonPressed != 0) updateMenuDisplay(buttonPressed); buttonPressed = 0; return; }
  else if (value < 700) { Serial.println("button 1"); buttonPressed = 1; }
  else if (value < 900) { Serial.println("button 2"); buttonPressed = 2; }
  else if (value < 1000) { Serial.println("button 3"); buttonPressed = 3; }
  else { Serial.println(value); buttonPressed = 0; }
}
static int lastSonarValue = 0;
void handleSonar() {
  int value = sonar.Distance();
  if (value > lastSonarValue + sonarVariance || value < lastSonarValue - sonarVariance) {
    Serial.println(value); lastSonarValue = value;
  }
}
static int lastMotion = 0;
void handleMotion() {
  int value = digitalRead(MOTION_IN);
  if (value != lastMotion) lastMotion = value;
  if (lastMotion) Serial.println("Motion Detected");
}
void handleLeds() {
  digitalWrite(LED_RED, eyeColor == RED || eyeColor == WHITE || eyeColor == PURPLE || eyeColor == YELLOW ? HIGH : LOW);
  digitalWrite(LED_GREEN, eyeColor == GREEN || eyeColor == WHITE || eyeColor == YELLOW ? HIGH : LOW);
  digitalWrite(LED_BLUE, eyeColor == BLUE || eyeColor == WHITE || eyeColor == PURPLE ? HIGH : LOW);
}
void handleRemote() {
  if (irRecv.decode(&irResults)) { translateIR(); irRecv.resume(); }
}
// Timer1中断
ISR(TIMER1_COMPA_vect) {
  sei(); // 允许嵌套中断
  updateServoPosition();
  if (timer_1000ms++ == TIMER_FREQUENCY) { timer_1000ms = 0; countDown--; if (countDown < 0) countDown = 0; }
  if (timer_2ms++ == TIMER_2MS) {
    timer_2ms = 0;
    if (digit == 0) updateTimeDisplay(1, countDown % 10);
    if (digit == 1) updateTimeDisplay(2, (countDown / 10) % 10);
    if (digit == 2) updateTimeDisplay(3, (countDown / 100) % 10);
    if (digit == 3) updateTimeDisplay(4, 16);
    digit = ((digit + 1) % 4);
  }
}
void playGame() {
  static int sequence = 0;
  static long internalTimer = millis();
  static bool closerClipPlayed = false;
  static bool hurryUpClipPlayed = false;
  static int captureDistance = 0;
  long currentTimer = internalTimer;
  if(isPlayingSound()) return;
  if (gameState == WARMUP) {
    if (sequence == 0) { Serial.println("Warming Up"); dfPlayer.playFolder(1, 1); faceTree = false; eyeColor = YELLOW; sequence++; }
    else if (sequence == 1 && countDown <= 30) { Serial.println("Laughing"); dfPlayer.playFolder(1, 2); faceTree = true; sequence++; }
    else if (sequence == 2 && countDown <= 10) { Serial.println("Almost ready"); dfPlayer.playFolder(1, 3); sequence++; }
    else if (sequence == 3 && countDown == 0) { Serial.println("All ready, lets play"); dfPlayer.playFolder(1, 4); faceTree = false; sequence = 0; gameState = WAIT; gameInPlay = false; }
  } else if (gameState == WAIT) {
    currentTimer = millis();
    if (gameInPlay) { gameState = READY; remotePlay = false; sequence = 0; }
    else if (currentTimer - internalTimer > 30000 || sequence == 0) {
      internalTimer = millis();
      if(playType == AUTO) { Serial.println("Press the go button when you are ready"); dfPlayer.playFolder(1, 5); }
      else { Serial.println("Press the power button on the remote when you are ready"); dfPlayer.playFolder(1, 6); }
      eyeColor = BLUE; faceTree = false; gameInPlay = false; sequence++;
    }
  } else if (gameState == READY) {
    currentTimer = millis();
    if (sequence == 0) { Serial.println("Get in position."); dfPlayer.playFolder(1, 7); countDown = 10; eyeColor = WHITE; faceTree = false; sequence++; internalTimer = millis(); }
    else if (sequence == 1) { if (playType == REMOTE) { if (remotePlay) sequence++; } else sequence++; }
    else if (sequence == 2) {
      if (countDown == 0) {
        countDown = playTimes[playTime];
        Serial.print("play time set to "); Serial.println(countDown);
        Serial.println("Here we go!"); dfPlayer.playFolder(1, 8);
        gameState = GREENLIGHT; sequence = 0;
      }
    }
  } else if (gameState == GREENLIGHT) {
    currentTimer = millis();
    if (sequence == 0) { eyeColor = GREEN; Serial.println("Green Light!"); dfPlayer.playFolder(1, 9); sequence++; }
    else if(sequence == 1) { dfPlayer.playFolder(1, 19); faceTree = true; sequence++; internalTimer = millis(); }
    else if (sequence == 2) {
      if (playType == AUTO && currentTimer - internalTimer > GREEN_LIGHT_MS) { sequence = 0; gameState = REDLIGHT; }
      else if (playType == REMOTE && remotePlay == false) { sequence = 0; gameState = REDLIGHT; }
      else {
        if (gameInPlay == false || lastSonarValue < WIN_PROXIMITY_CM) { sequence = 0; gameState = WIN; }
        else if (countDown <= 0) { Serial.println("Out of Time"); dfPlayer.playFolder(1, 16); sequence = 0; gameState = LOSE; }
        else if (lastSonarValue < CLOSE_PROXIMITY_CM && closerClipPlayed == false) { Serial.println("Getting closer!"); dfPlayer.playFolder(1, 11); closerClipPlayed = true; }
        else if (countDown <= BETTER_HURRY_S && hurryUpClipPlayed == false) { Serial.println("Better Hurry"); dfPlayer.playFolder(1, 12); hurryUpClipPlayed = true; }
      }
    }
  } else if (gameState == REDLIGHT) {
    currentTimer = millis();
    if (sequence == 0) { eyeColor = RED; Serial.println("Red Light!"); if(language == ENGLISH) dfPlayer.playFolder(1, 10); else dfPlayer.playFolder(1, 18); sequence++; }
    else if(sequence == 1) { dfPlayer.playFolder(1, 19); faceTree = false; captureDistance = lastSonarValue; sequence++; internalTimer = millis(); }
    else if (sequence == 2) {
      if (lastMotion == 0 || (currentTimer - internalTimer) > WAIT_FOR_STOP_MOTION_MS) { internalTimer = millis(); sequence++; Serial.println("Done settling"); }
      Serial.println("Waiting to settle");
    }
    else if (sequence == 3) {
      if (playType == AUTO && currentTimer - internalTimer > RED_LIGHT_MS) { sequence = 0; gameState = GREENLIGHT; }
      else if (playType == REMOTE && remotePlay == true) { sequence = 0; gameState = GREENLIGHT; }
      else {
        if (gameInPlay == false || lastMotion == 1 || lastSonarValue < captureDistance) { Serial.println("Movement detected!"); dfPlayer.playFolder(1, 15); sequence = 0; gameState = LOSE; }
        if (countDown == 0) { Serial.println("Out of time"); dfPlayer.playFolder(1, 16); sequence = 0; gameState = LOSE; }
      }
    }
  } else if (gameState == WIN) {
    if (sequence == 0) { Serial.println("You Won!"); dfPlayer.playFolder(1, 13); eyeColor = WHITE; faceTree = false; sequence++; }
    else if (sequence == 1) { Serial.println("Play Again?"); dfPlayer.playFolder(1, 17); gameInPlay = false; countDown = 0; gameState = WAIT; sequence = 0; }
  } else if (gameState == LOSE) {
    if (sequence == 0) { Serial.println("Sorry, you lost"); dfPlayer.playFolder(1, 14); eyeColor = PURPLE; faceTree = false; sequence++; }
    else if (sequence == 1) { Serial.println("Play Again?"); dfPlayer.playFolder(1, 17); gameInPlay = false; countDown = 0; gameState = WAIT; sequence = 0; }
  } else { gameState = WARMUP; }
}
void loop() {
  if (task_50ms.fire()) { handleRemote(); handleButtons(); }
  if (task_250ms.fire()) { handleSonar(); handleMotion(); handleLeds(); playGame(); Serial.println(isPlayingSound()); }
}
void setupTimer() {
  cli();
  TCCR1A = 0; TCCR1B = 0; TCNT1 = 0;
  OCR1A = TIMER_MATCH;
  TCCR1B |= (1 << WGM12);
  TCCR1B |= (1 << CS11) | (1 << CS10);
  TIMSK1 |= (1 << OCIE1A);
  sei();
}
void setup() {
  Serial.begin(9600);
  pinMode(MOTION_IN, INPUT);
  pinMode(BUTTONS_IN, INPUT);
  pinMode(DFPLAYER_BUSY_IN, INPUT);
  pinMode(SERVO_OUT, OUTPUT);
  pinMode(LED_RED, OUTPUT); pinMode(LED_GREEN, OUTPUT); pinMode(LED_BLUE, OUTPUT);
  pinMode(SEGMENT_LATCH, OUTPUT); pinMode(SEGMENT_CLOCK, OUTPUT); pinMode(SEGMENT_DATA, OUTPUT);
  pinMode(SEGMENT_1_OUT, OUTPUT); pinMode(SEGMENT_2_OUT, OUTPUT); pinMode(SEGMENT_3_OUT, OUTPUT);
  irRecv.enableIRIn();
  dfPlayer.begin(Serial); dfPlayer.volume(VOLUME);
  lcdDisplay.init(); lcdDisplay.backlight();
  setupTimer();
  lcdDisplay.setCursor(0, 0); lcdDisplay.print("Welcome to the");
  lcdDisplay.setCursor(0, 1); lcdDisplay.print("Squid Games!");
  delay(1000);
  task_50ms.begin(50);
  task_250ms.begin(250);
}
项目文件

所有构建文件:https://github.com/CodeMakesItGo/SquidGamesDoll

原理图

所有元件与UNO连接方式:

自制《鱿鱼游戏》主题互动娃娃——Arduino UNO DIY项目
项目仓库

完整文件:https://github.com/CodeMakesItGo/SquidGamesDoll

制造工艺

  1. 用 Arduino 打造绚丽显示器 Ambilight 系统
  2. 用 Arduino UNO 和 OLED 显示屏制作经典 Pong 游戏:分步教程
  3. 基于 Arduino Uno 的人体检测救援机器人:传感器集成分步指南
  4. Arduino 与智能手机打造智能电压表——简单易做的 DIY 项目
  5. 基于 Arduino 与 MAX30100 的实时物联网心率监测系统
  6. Arduino Uno WiFi 网页服务器:通过浏览器控制 LED 开关
  7. Arduino 串口简易计算器:两数四则运算演示
  8. Arduino 声纳实时测距与 Processing 可视化
  9. 自制便携式视觉暂留显示器:Arduino UNO 与 ATtiny85
  10. Arduino Mega 2560 综合实训平台 - 传感器/电机/显示/PCB 一体化开发板
  11. 使用 Nextion 显示屏构建 Fridgeye 应用:分步指南
  12. 使用 Arduino Nano 和 RDA8057M 制作紧凑型 FM 收音机